连续分享了几篇图表
想必大家也是眼睛疲劳了，所以我们今天讲讲函数
主题就是SUMIFS函数！
你可能觉得SUMIFS很简单
但是，真的学会了吗？
SUMIFS
我们一起来看看吧！
数据源（注意：图片大小限制，实际明细数据很多）：
我们从简单开始，慢慢介绍
1、 空调 的金额合计
=SUMIFS(C:C,A:A,"空调")
对应的SUMIF
=SUMIF(A:A,"空调",C:C)
注意SUMIF 是求和区域在后，而 SUMIFS 是求和区域在前
因为条件个数不确定
2、 1月 软性饮料 的金额合计
=SUMIFS(C:C,A:A,"软性饮料",D:D,1)
3、 1月 和 2月 的软性饮料金额合计
你可能已经默默在心里说了，这个我会？相加呗！没错，但是不推荐
如果条件较多，就开火车了
不推荐的火车：
=SUMIFS(C:C,A:A,"软性饮料",D:D,1)+SUMIFS(C:C,A:A,"软性饮料",D:D,2)
推荐写法：
=SUM(SUMIFS(C:C,A:A,"软性饮料",D:D,{1,2}))
更多条件只需要在{}中写即可
4、1月 香烟和 1月 烈酒的金额合计
=SUM(SUMIFS(C:C,A:A,{"香烟","烈酒"},D:D,1))
注意这里香烟和烈酒是文本需要加双引号，不同于上面的1和2
5、金额小于500的合计数
=SUMIFS(C:C,C:C,"<500")
求和列本身也可以作为条件列一起
6、商品名称为 两个字 的金额合计
=SUMIFS(C:C,A:A,"??")
注意这里?是通配符，表示任意1个字符，注意是英文状态下
7、书籍金额合计（包括儿童和成人两类）
=SUMIFS(C:C,A:A,"*书籍")
这里的*是任意0个或者多个字符，这里可以理解为已书籍结尾的意思
8、1月到3月间的金额合计
注意这里假设没有月份列，我们要使用日期作为条件
9、包含 书 的金额合计
=SUMIFS(C:C,A:A,"*书*")
这里*同样表示通配符，表示包含的意思，以什么开始就是XX*
不再举栗！
10、香烟和烈酒的1月和2月合计
也就是1、2月的香烟+1、2月的烈酒
=SUM(SUMIFS(C:C,A:A,{"香烟","烈酒"},D:D,{1;2}))
新手同学的火车：
=SUMIFS(C:C,A:A,"香烟",D:D,1)+SUMIFS(C:C,A:A,"香烟",D:D,2)+SUMIFS(C:C,A:A,"烈酒",D:D,1)+SUMIFS(C:C,A:A,"烈酒",D:D,2)
注意1;2之间是分号，{"香烟","烈酒"} 是逗号
逗号，表示行，分号表示列，交叉形成4个条件
小结：
函数博大精深，每个参数变化无穷，你以为你已经学完的时候，其实可能那才是入门的开始，今天我们简单总结了一下比较常用的SUMIF(S)函数，可见一斑！
你平时有像文中一样开过"火车"吗？
最后：建议收藏备查或学习！
特别声明：以上内容(如有图片或视频亦包括在内)为自媒体平台“网易号”用户上传并发布，本平台仅提供信息存储服务。
Notice: The content above (including the pictures and videos if any) is uploaded and posted by a user of NetEase Hao, which is a social media platform and only provides information storage services.
