Vlookup函数最经典的14种用法，用过的人都说香，错过后悔一个亿！

点击关注 【秋叶 Excel】

发送【7】 领 1000 篇 Excel 精选教程！

作者：竺兰

编辑：竺兰

PS.文末下载配套练习文件！

对于得了函数恐惧症的 Excel 小白来讲，最最最最最痛苦的事情是什么？

不知道用哪个函数？

是我明明知道这个函数的名字，却不知道怎么写公式！

就比如在 Excel 界「称霸一方」的查找函数 VLOOKUP，悬浮窗早已给出了答案，但在小白眼里就是一堆神秘字符。

所以今天，我为大家准备了14 个常见常用的 VLOOKUP 函数经典用法，助力大家提高效率准点下班。

单条件查找

案例：根据条件「葡萄」，查找「数量」。

公式：

=VLOOKUP(E2,B2:C21,2,FALSE)

VLOOKUP 基本语法见下图：

隐藏乱码

案例：隐藏 F 列出现的乱码#N/A。

公式：

=IFERROR(VLOOKUP(E2,B2:C21,2,FALSE),"")

公式说明：""的含义是：如果前面的 VLOOKUP 函数中存在错误的参数，那么在显示结果的单元格中显示为空。

多条件查找

案例：根据两个条件「姓名」和「科目」，查找「成绩」。

公式：

=VLOOKUP(F3&G3,A:D,4,FALSE)

公式说明：添加辅助列，将两个条件用&符号组合在一起，变成一个条件，再用 VLOOKUP 函数的基础语法进行查找。

模糊查找

案例：根据「课程简称」，查找「课程全称」。

公式：

=VLOOKUP("*"&C2&"*",$A$1:$A$8,1,FALSE)

公式说明：将要查找的简称前后都用&连接符加上一个「*」，就可以来替代包含该简称的数据了。

分段统计

案例：根据「金额」，查看所在「区间」。

公式：

=VLOOKUP(C2,$F$2:$G$9,2,TRUE)

公式说明：

❶ 使用了 VLOOKUP 近似匹配的特殊用法，第四参数，需用 True，或者 1；

❷ 区间起点必须是第 2 参数区域的首列；

❸ 第 2 参数区域需用 $ 锁定，确保不偏移。

注意：使用这个公式有条件限制。一是查找值必须为数字；二是查找区域的数字必须从小到大排序。

如果你想轻松学习一门 Excel 技能，解决职场实际需求，提高效率，可以来秋叶 Excel 3 天集训营哦~

秋叶 Excel 3 天集训营

3 天学习+课后实践+助教答疑

现在加入

免费学习

还送【35 个函数使用说明手册】

案例：根据「姓名」，查找一月、二月、三月的「销售额」。

公式：

=VLOOKUP($A15,$A$2:$D$12,COLUMN(B1),0)

公式说明：Column(B1)的结果是 2，当公式向右复制时可以生成 3，4，5，……

逆向查找

案例：查找区域「编号」列在返回区域「水果」列的左侧，可以使用 VLOOKUP+IF 函数来进行查找。

公式：

=VLOOKUP(E2,IF({1,0},B2:B21,A2:A21),2,FALSE)

公式说明：利用 IF 函数构造数组，将 B 列和 A 列位置互换，再用 VLOOKUP 函数正常查找。

多表查找

如果参与匹配的表有多个，并且可以通过条件来判断数据存在于哪张表，还是可以用 VLOOKUP+IF 函数的组合来实现多表查找。

案例：不同店铺的数据放在不同的表格中，需要查找 2 店编号 005 产品的数量。

公式：

=VLOOKUP(B2,IF(A2="1 店",A6:C12,E6:G14),3,0)

公式说明：用 IF 函数判断 A2 单元格的数值是否为 1 店，是则返回 A6:C12，不是则返回 E6:G14。然后用 VLOOKUP 查找。

跨表查找

如果不知道查找值位于哪张工作表，或者表的数量太多，可以使用：

VLOOKUP+INDIRECT+LOOKUP+COUNTIF

案例：根据「水果」，在多个表格查找数量。

公式：

=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT({"水果 1";"水果 2";"水果 3"}&"!A:A"),A2),{"水果 1";"水果 2";"水果 3"})&"!A:B"),2,0)

公式说明：

A2：VLOOKUP 的查找值；

{...}数组里的内容：多个工作表名称，用分号分隔；

A:A：查找值在各个表中的哪一列，需要确定各个表的该列是否存在这个查找值；

A:B：VLOOKUP 的查找区域；

2：返回值的列数，姓名是在 A:B 区域中的第 2 列。

如果还想掌握更多 Excel 实用技巧~

建议你 来秋叶 Excel 3 天集训营，由大神带你学习表格设计+数据处理+数据可视化，让工作更轻松！

秋叶 Excel 3 天集训营

原价 99 元

现在限时免费

添加 Excel 班主任微信

助你提高效率、升职加薪！

交叉查询

案例：根据「列号」和「行号」，查找姓名。

公式：

=VLOOKUP(I2,A2:F11,MATCH(I1,A1:F1,0))

公式说明：用 MATCH 得出的结果即为 VLOOKUP 函数第 3 参数，返回被查找区域的第几列。

查找最后一个值

案例：查询「水果」的「最后一次销量」。

公式：

=VLOOKUP(COUNTIF($C$2:$C$11,F2)&F2,$B$1:$D$11,3,FALSE)

公式说明：关于用 COUNTIF 函数做辅助列查找最后一个出现的值相关的做法，之前有一篇文章讲过：

不规范数据查找

如果数据肉眼看上去一模一样，但怎么都查找不到，很有可能是因为数据当中存在空格或不可见字符。

这时可以使用 SUBSTITUTE 或 CLEAN 函数处理数据，再进行查找。

案例：根据条件「葡萄」，查找「数量」。

公式：

=VLOOKUP(SUBSTITUTE(E2," ",""),B2:C21,2,0)

公式说明：先用 SUBSTITUTE 函数将「橙子 」后面的空格替换成空，再用 VLOOKUP 查找。同理，如果是不可见字符，则使用 CLEAN 函数处理数据。

查找区域有合并单元格

查找区域存在合并单元格，会导致 VLOOKUP 无法正确查找到数据，因为合并单元格只有最左上角的单元格有数据，其他单元格都为空。

这时可以考虑用 VLOOKUP+OFFSET+MATCH 来完成查找。

案例：根据科目和姓名查找学生的成绩。

公式：

=VLOOKUP(G3,OFFSET($B$2,MATCH(F3,A:A,)-1,):C22,2,0)

公式说明：MATCH 函数定位科目所在的行号，用 OFFSET 向下偏移获得「动态查找区域」，最后用 VLOOKUP 查找。

查找值为合并单元格

如果查找值也存在合并单元格，可以用两个 VLOOKUP 嵌套完成查找。

案例：根据部门查找月度奖金。

公式：

=VLOOKUP(VLOOKUP("座",$D$2:D2,1),$A$2:$B$4,2,0)

公式说明：在$D$2:D2 这个范围里查找「座」这个文本，然后返回这个词在这个区域里的最后一个文本，如果找不到，就返回这个区域里最后一个文本值。再用第二个 VLOOKUP 去查找。

VLOOKUP 的作用非常之强大，祝愿大家早日掌握！

Excel 中如此实用的函数还有很多，如果你还在为重复工作而烦恼，想提高效率节省时间做副业或享受生活，那一定要来《秋叶 Excel 3 天集训营》！

这里不仅有专业老师手把手教你表格排版+数据统计+图表可视化，还有贴心助教随时为你解答问题~

秋叶 Excel 3 天集训营

现在免费报名

送 35 个常用函数说明

赶紧点击加入

最后用一张图简单总结下，本文介绍的所有 VLOOKUP 函数用法

当然啦，只看不练是很难学会 VLOOKUP 的，所以我还整理了一份练习文件，大家在【秋叶Excel】公众号后台回复关键词VVV获取哦！

每天学点 Excel，工作效率 up~up~我们明天见！

点击关注【秋叶 Excel】

回复关键词VVV领取本文练习文件